VBScript 使用 WMI 找出 SQL Server 版本

问题描述

谁能指点我一个 vbscript(使用 WMI)来找出安装的 SQL Server 版本.我有一个场景，可以在一台机器上安装 SQL Server 2008 R2 或 SQL Server 2012.

Can anyone point me to a vbscript (using WMI) to find out the installed SQL Server version. I have a scenario where either SQL Server 2008 R2 or SQL Server 2012 could be installed on a machine.

推荐答案

基于 此处的第一个 Google 搜索结果:

Dim WMI, Col, Prod, Q
Set WMI = GetObject("WinMgmts:")
Q = "Select * FROM Win32_Product WHERE Vendor = " & _
    "'Microsoft Corporation' AND Name LIKE 'SQL Server%Database Engine Services'"
Set Col = WMI.ExecQuery(Q)
For Each Prod in Col
  if left(Prod.version, 3) = "11." then
    msgbox "SQL Server 2012 was found!" & vbCrLf & prod.version
  elseif left(Prod.version, 4) = "10.5" then
    msgbox "SQL Server 2008 R2 was found!" & vbCrLf & prod.version
  end if
Next
Set Col = Nothing
Set WMI = Nothing

请注意，WMI 不是执行此操作的最快方法.您是否考虑过直接检查注册表而不是通过 WMI?

Note that WMI is not the fastest way to do this. Have you considered checking the registry directly instead of going through WMI?

UPDATE 给出 OP 的解决方案使用注册表，并假设可以安装 2008R2 或 2012 中的一个:

UPDATE given OP's solution using the registry instead, and with the assumption that exactly one of 2008R2 or 2012 could be installed:

RegKey2012 = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\" & _
             "Microsoft SQL Server\MSSQL11.MSSQLSERVER\"
If RegKeyExists(RegKey2012) Then 
  WScript.StdOut.Write("2012") 
Else 
  WScript.StdOut.Write("2008R2") 
End If 

Function RegKeyExists(Key) 
  Dim oShell, entry 
  On Error Resume Next 
  Set oShell = CreateObject("WScript.Shell") 
  entry = oShell.RegRead(Key) 
  If Err.Number <> 0 Then 
    Err.Clear 
    RegKeyExists = False 
  Else 
    Err.Clear 
    RegKeyExists = True 
  End If 
End Function

这篇关于VBScript 使用 WMI 找出 SQL Server 版本的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持跟版网！